KAGRA official sensitivity

Recovered on 2013.7.24.

Off[General::"spell1"]
Off[General::"spell"]

SetDirectory[NotebookDirectory[]];

1. Parameters for LCGT

1.1 Physical constants

hb=1.05457266912510183 (10^(-34));(* reduced Planck constant (J*s) *)
ω0=1.8 (10^15);
c=2.99792458000000117`*^8;(* speed of light (m/s) *)
Ω=2 π f;
kB=1.38*10^(-23);(* Boltzmann's constant (J/K) *)
g=9.8;(* acceleration of the gravity (m/s^2) *)
L=3000;

1.2 Laser

lambda=1064*10^(-9);(* wavelength (m) *)

1.3 Main cavity

l=3*10^3;(* length of cavity (m) *)
w1=3.0*10^(-2); (* ITM beam radius at mirrors (m) *)
w2=3.0*10^(-2); (* ETM beam radius at mirrors (m) *)

1.4 Mirror

rho=4.0*10^3;(* density (kg/m^3) *)
radius=12.5*10^(-2);(* radius (m); used to be 12.5cm *)
height=15*10^(-2);(* height (m) *)
mass= rho*Pi*radius^2*height;(* mass (kg) *)
Tm=20;(* temperature of mirror (K) *)
E0=4.0*10^(11);(* Young's modulus (Pa) *)
sigma = 0.29;(* Poisson ratio *)
Qmirror=10^(8);(* loss angle of material *)
alpha20=5.6*10^(-9);(* thermal expansion coefficient at 20K (/K) *)
Cth20=0.69;(* specific heat at 20 K (J/kg*K) *)
kappa20=1.57*10^4;(* thermal conductivity at 20 K (W/m*K) *)

1.5 Coating

Ncoa1=9;
Ncoa2=18;

Ys=7.2*10^10;(* Young's modulus for silica (Pa=N/m^2) *)
Yt=1.4*10^11;(* Young's modulus for Ta2O5 (Pa=N/m^2) *)
σs = 0.17;(* Poisson ratio for silica *)
σt = 0.23;(* Poisson ratio for Ta2O5 or sapphire *)
n1=1.45; (* Refraction index of silica *)
n2=2.07; (* Refraction index of tantala *)
dcoa1s=(Ncoa1-1)/4*10^(-6)/n1;(* thickness of ITM silica coating (m) *)
dcoa1t=Ncoa1/4*10^(-6)/n2;(* thickness of ITM tantala coating (m) *)
dcoa2s=(Ncoa2-1)/4*10^(-6)/n1;(* thickness of ETM silica coating (m) *)
dcoa2t=Ncoa2/4*10^(-6)/n2;(* thickness of ETM tantala coating (m) *)
ϕc1=1.0*10^(-4);(* loss angle of silica coating *)
ϕc2=4.0*10^(-4);(* loss angle of tantala coating *)

Cs=1.64 10^6;
κs=1.38/Cs;
αexps=5.1 10^-7;
Ct=2.1 10^6;
κt=33/Ct;
αexpt=3.6 10^-6;

1.6 Suspension

Parameters

ω=Ω;

I2=(π/4)(r2^4);

r2=0.0018/2; (* 1W heat extraction *)

Y2=400*(10^9); (* Sapphire *)

N2=4;

lsus2=0.4;

Tp=16;

ϕp=2*(10^(-7)); (* Sapphire *)

VHC=1/200;

Ksusp

lsus=lsus2; 
dwire=2*r2;
Ewire=Y2;

n=N2;

Icwire=I2;(* moment of cross section (m^4) *)

ksus[f_]=Sqrt[(-mass*g/n+Sqrt[(mass*g/n)^2+4*Ewire*(1+I ϕp)*Icwire*rho*Pi*(dwire/2)^2*(2*Pi*f)^2])/(2*Ewire*(1+I ϕp)*Icwire)];

kele[f_]=Sqrt[(mass*g/n+Sqrt[(mass*g/n)^2+4*Ewire*(1+I ϕp)*Icwire*rho*Pi*(dwire/2)^2*(2*Pi*f)^2])/(2*Ewire*(1+I ϕp)*Icwire)];

Ksusp[f_]=n*(2*Pi*f)Sqrt[rho*Pi*(dwire/2)^2*Ewire*(1+I ϕp)*Icwire]*(2*Pi*f)^2*Sqrt[(mass*g/n)^2+4*Ewire*(1+I ϕp)* Icwire*rho*Pi*(dwire/2)^2*(2*Pi*f)^2]*(ksus[f]*Sin[ksus[f]*lsus]+kele[f]*Cos[ksus[f]*lsus]*Tanh[kele[f]*lsus])/(mass*g/n*(2*Pi*f)^2*Sin[ksus[f]*lsus]*Tanh[kele[f]*lsus]-2*(2*Pi*f)^3*Sqrt[rho*Pi*(dwire/2)^2*Ewire*(1+I ϕp)*Icwire]*(Cos[ksus[f]*lsus]-1/Cosh[kele[f]*lsus]));

2. Seismic noise

hseis[f_]=(10^(-9))(f^(-2))*(10^(-3))(f^(-6))*2/L;

3. Thermal noise

3.1 Suspension (ITM+ETM) by PPP

hsusp[f_]=(2/L)*Sqrt[Abs[4*kB*Tp/(2*Pi*f)^2*Re[I*2*Pi*f/(Ksusp[f]-mass*(2*Pi*f)^2)]]];

3.2 Mirror

3.2.1 Mirror (homogeneous structural damping)

hmirrorstr[f_]=((Sqrt[2])/L)*Sqrt[4*kB*Tm*(1-sigma^2)/(Sqrt[Pi]*E0*w1*Qmirror*2*Pi*f)+4*kB*Tm*(1-sigma^2)/(Sqrt[Pi]*E0*w2*Qmirror*2*Pi*f)];

3.2.2 Mirror (thermoelastic damping)

Jhyper=(1/( ((Ωc)^2)))(1-Re[(E^((Ωc I)/2)) ((1-Ωc I)(1- Erf[(((Sqrt[Ωc]) (1+I))/2)]))])-(Sqrt[(1/(π ((Ωc)^3)))]);
Ωc=π Cs2 (w0^2)f/kappa20/.Cs2->Cth20*rho;

hmirrorthermo[f_]=(2/L)*Sqrt[2/Sqrt[Pi]*alpha20^2*(1+sigma)^2*kB*Tm^2*Sqrt[1/(kappa20*rho*Cth20)]/Sqrt[2*Pi*f]];

3.2.3 Mirror (coating: structural damping)

hmirrorcoa[f_]=((Sqrt[2])/L)√(((4 kB Tm dcoa1s ϕc1)/(π (w1^2)Ω))(((Ys^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σs))^2)(1-2σs))/((E0^2)Ys(1-((σs)^2))))+((4 kB Tm dcoa1t ϕc2)/(π (w1^2)Ω))(((Yt^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σt))^2)(1-2σt))/((E0^2)Yt(1-((σt)^2))))+((4 kB Tm dcoa2s ϕc1)/(π (w2^2)Ω))(((Ys^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σs))^2)(1-2σs))/((E0^2)Ys(1-((σs)^2))))+((4 kB Tm dcoa2t ϕc2)/(π (w2^2)Ω))(((Yt^2)(((1+sigma))^2)(((1-2sigma))^2)+(E0^2)(((1+σt))^2)(1-2σt))/((E0^2)Yt(1-((σt)^2)))));

3.2.5 Total (ITM+ETM; low temperature; TO is ignored)

hmirror[f_]=Sqrt[hmirrorstr[f]^2+hmirrorthermo[f]^2+hmirrorcoa[f]^2];

4. Optical readout noise (no ζ)

4.1 Additional parameter settings

T=0.004;

m=mass; (* test mass (kg) *)
P0= 75;(* power into interderometer(W)*)
Gpower=11;(* power recycling gain *)
I0=P0*Gpower; (* incident power to the beamsplitter *)

ρ=0.92;

4.2 Basic equations for RSE

hSQL=(Sqrt[((8 hb)/(m (Ω^2) (L^2)))]);

Sh=((hSQL^2)/(2 κ))(((Abs[C11 Sin[ζ]+C21 Cos[ζ]])^2)+((Abs[C12 Sin[ζ]+C22 Cos[ζ]])^2)+((Abs[P12 Sin[ζ]+P22 Cos[ζ]])^2)+((Abs[P11 Sin[ζ]+P21 Cos[ζ]])^2)+((Abs[Q12 Sin[ζ]+Q22 Cos[ζ]])^2)+((Abs[Q11 Sin[ζ]+Q21 Cos[ζ]])^2)+((Abs[N11 Sin[ζ]+N21 Cos[ζ]])^2)+((Abs[N12 Sin[ζ]+N22 Cos[ζ]])^2)+(((Abs[M]*(Sqrt[Sadd])))^2))/((τ^2) ((Abs[D1sig Sin[ζ]+D2sig Cos[ζ]])^2));

M=1+(ρ^2)Exp[4 I β]-2ρ(Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+λSR ρ(-ρ Exp[2 I β]+Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+ϵ ρ(2((Cos[β])^2)(-ρ Exp[2 I β]+Cos[2ϕ])+(κ/2)(3+Exp[2 I β])Sin[2ϕ])Exp[2 I β];
C11=(Sqrt[1-λPD])((1+(ρ^2)) (Cos[2 ϕ]+(κ/2) Sin[2 ϕ])-2 ρ Cos[2 β]-(1/4)ϵ(-2(((1+Exp[2 I β]))^2)ρ+4(1+(ρ^2))((Cos[β])^2)Cos[2ϕ]+(3+Exp[2 I β])κ(1+(ρ^2))Sin[2 ϕ])+λSR(Exp[2 I β]ρ-(1/2)(1+(ρ^2))(Cos[2 ϕ]+(κ/2)Sin[2ϕ])));
C12=(Sqrt[1-λPD])(τ^2) ( -Sin[2 ϕ]-κ  ((Sin[ϕ])^2)+(1/2)ϵ Sin[ϕ]((3+Exp[2 I β])κ Sin[ϕ]+4 ((Cos[β])^2)Cos[ϕ])+(1/2)λSR(Sin[2ϕ]+κ ((Sin[ϕ])^2)));
C21=(Sqrt[1-λPD])(τ^2) (Sin[2 ϕ]-κ  ((Cos[ϕ])^2)+(1/2)ϵ Cos[ϕ]((3+Exp[2 I β])κ Cos[ϕ]+4 ((Cos[β])^2)Sin[ϕ])+(1/2)λSR(-Sin[2ϕ]+κ ((Cos[ϕ])^2))) ;
C22=C11;
D1sig=(Sqrt[1-λPD])(-(1+ρ Exp[2 I β]) Sin[ϕ]+(1/4)ϵ(3+ρ+2ρ Exp[4 I β]+(1+5ρ)Exp[2 I β])Sin[ϕ]+(1/2)λSR Exp[2 I β]ρ Sin[ϕ]);
D2sig=(Sqrt[1-λPD])(-(-1+ρ Exp[2 I β]) Cos[ϕ]+(1/4)ϵ(-3+ρ+2ρ Exp[4 I β]+(-1+5ρ)Exp[2 I β])Cos[ϕ]+(1/2)λSR Exp[2 I β]ρ Cos[ϕ]);
P11=(1/2)(Sqrt[1-λPD])(Sqrt[λSR])τ(-2ρ Exp[2 I β]+2Cos[2ϕ]+κ Sin[2ϕ]);
P12=-(Sqrt[1-λPD])(Sqrt[λSR])τ Sin[ϕ](2Cos[ϕ]+κ Sin[ϕ]);
P21=(Sqrt[1-λPD])(Sqrt[λSR])τ Cos[ϕ](2Sin[ϕ]-κ Cos[ϕ]);
P22=P11;
Q11=(Sqrt[λPD])(Exp[-2 I β]+(ρ^2)Exp[2 I β]-ρ(2 Cos[2ϕ]+κ Sin[2 ϕ])+(1/2)ϵ ρ(Exp[-2 I β]Cos[2ϕ]+Exp[2 I β](-2ρ-2ρ Cos[2 β]+Cos[2ϕ]+κ Sin[2ϕ])+2 Cos[2ϕ]+3 κ Sin[2ϕ])-(1/2)λSR ρ(2ρ Exp[2 I β]-2 Cos[2ϕ]-κ Sin[2ϕ]));
Q12=0;
Q21=0;
Q22=Q11;

N11=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(κ(1+ρ Exp[2 I β])Sin[ϕ]+2Cos[β](Exp[-I β]Cos[ϕ]-ρ Exp[I β](Cos[ϕ]+κ Sin[ϕ])));
N12=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(Exp[-I β]+ρ Exp[I β])Cos[β]Sin[ϕ];
N22=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(-Exp[-I β]+ρ Exp[I β])Cos[β]Cos[ϕ];
N21=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(-κ(1+ρ)Cos[ϕ]+2Cos[β](Exp[-I β]+ρ Exp[I β])Cos[β] Sin[ϕ]);

N11=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(κ(1+ρ Exp[2 I β])Sin[ϕ]+2Cos[β](Exp[-I β]Cos[ϕ]-ρ Exp[I β](Cos[ϕ]+κ Sin[ϕ])));
N12=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(-Exp[-I β]+ρ Exp[I β])Cos[β]Sin[ϕ]; (* wrong! *)
N21=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(Exp[-I β]+ρ Exp[I β])Cos[β]Cos[ϕ]; (* wrong! *)
N22=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(-κ(1+ρ)Cos[ϕ]+2Cos[β](Exp[-I β]+ρ Exp[I β])Cos[β] Sin[ϕ]); (* wrong! *)

γ=T c/(4 L);(* cavity pole *)
τ=(Sqrt[1-(ρ^2)]); (* SRM transmittance *)
β=ArcTan[Ω/γ]; (* phase shift in the arm cavity *)
κ=((2 (I0/ISQL) (γ^4))/((Ω^2) ((γ^2)+(Ω^2)))); (* coefficient that shows how much the mirror moves *)
ISQL=((m (L^2) (γ^4))/(4 ω0)); (* the power with which the quantum noise reaches the SQL at the cavity pole frequency *)

4.3 Loss parameters

roundtriploss=100*10^(-6); (* ppm *)
ϵ = 2/T*roundtriploss; (* loss parameter of arms defined in KLMTV paper *)
λSR =0.02; (* loss in power at the signal recycling mirror *)
λPD=0.1;  (* 1 - PD's quantum efficiency in power *)
Sadd= 0*((π^2)/8 - 1);

5.Observable distance (Compact binary coalescense)

5.1 Parameters

Gravity=6.673*10^(-11);(* Gravitational constant (m^3/Kg/s^2) *)
solarmass=1.989*10^(30);(* mass of Sun (Kg) *)
Mpc=365.2422*24*60*60*c*3.26*10^6;(* 1 Mpc (m) *)

mtotal=1.4*solarmass+1.4*solarmass;(* total moss of binary system (Kg) *)
mreduce=1.4*solarmass*1.4*solarmass/mtotal;(* reduced mass of binary system (Kg) *)
fmin=20;(* low cut off frequency of integral (Hz) *)
fmax=c^3/(6^(3/2)*Pi*Gravity*mtotal);(* high cut off frequency of integral (Hz) *)
SNR=8;(* threshold of Signal to Noise Ratio *)

5.2 Observable distance (Optimal case)

5.2.1 Integration

fmid=300;
Nini=60;
Nmid=20;

integ092=((∑_(ff=1)^Nini)(1/(f^(7/3)*(Sh+hsusp[f]^2+hmirror[f]^2+hseis[f]^2))*(fmid-fmin)/Nini/.f->fmin+(fmid-fmin)*(ff-0.5)/Nini))+((∑_(ff=1)^Nmid)(1/(f^(7/3)*(Sh+hsusp[f]^2+hmirror[f]^2+hseis[f]^2))*(fmax-fmid)/Nmid/.f->fmid+(fmax-fmid)*(ff-0.5)/Nmid));

5.2.2 vRSE

RangeAll=FindMaximum[(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc,{{ϕ,1.0,1.6},{ζ,0.01,1.57}}]

Inspiral range

Optimal direction

(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc/.ϕ->1.511/.ζ->-0.791

Sky average (old)

(1/SNR)*(1/2)*(32/7)^(1/3)*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc/.ϕ->1.511/.ζ->-0.791

Sky average (new); 0.442478 is given by Kanda-san.

(1/SNR)*2*0.442478*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc/.ϕ->1.511/.ζ->-0.791

6. Data Output

logDataOutput[filename_String, X_, {imin_, imax_}] :=
  Module[{strm},
    strm = OpenWrite[filename];
    Do[
      Do[
        Module[{},
          Map[writeList[strm, #] &, { x , X} /. x -> (10^i) 10^ j];
          writeListn[strm];
          ],
        {i, 0.001, 1, 0.001}
        ],
      {j, imin, imax}
      ];
    Close[strm];
    ]

writeList[strm_, dat_] :=
  WriteString[strm, ToString[FortranForm[dat]], " "];

writeListn[strm_] :=
  WriteString[strm, "\n"];

logDataOutput["totalVDRSE.dat",(Sqrt[Sh+hmirror[f]^2+hseis[f]^2+hsusp[f]^2])/.ϕ->1.511/.ζ->-0.791/.{f->x},{0,3}]