# class name
class PonderomotiveSqueezer

### parameters ############################################################

const Pin 125

# Lenghts and modulations
const Larm 3000
const Lprc 66.591
const Lsrc 66.591
const Lprbs 41.592
const Schnupp 3.33
const Lp1 14.7615 
const Lp2 11.0661
const Lp3 15.7638
const Ls1 15.7386
const Ls2 11.1115
const Ls3 14.7412

# Reflectivities
const Tprm 0.1
const Titm 0.004
const Tetm 0.0055
const Tsrm 0.1536
const Losses_arm 100e-6
const Tbs 0.5
const Tpr2 0e-6
const Tpr3 0e-6
const Tsr2 0e-6
const Tsr3 0e-6

# Curvatures
const RcITM -1900
const RcETM 1900
const RcPRM -458.1285
const RcPR2 -3.0764
const RcPR3 24.9165
const RcSRM 458.1285
const RcSR2 -2.9872
const RcSR3 24.9165
# AoI for recycling mirrors
const phi_aoi 0.6293


# Operating point
# DARM offset
const DARMtuning 1e-11
# Detuning
const SRCphi 0

### Optical configuration #################################################

# input laser and modulators
laser laser nL P=Pin
space sInj nL nPO L=1
# PO for homodyne LO
beamsplitter BS_PO nPO nPO1 nSP1 nPOd R=0.05
space sINP1 nSP1 nPRC1 L=1

# power recycling mirror and common part of the cavity
mirror PRM nPRC1 nPRC2 T=Tprm Rc=RcPRM
space sPRC1 nPRC2 nPRC3 Lp1 
beamsplitter PR2 nPRC4 nPRC3 dummy1 dummy2 T=Tpr2 Rc=RcPR2 aoi=phi_aoi
space sPRC2 nPRC4 nPRC5 Lp2
beamsplitter PR3 nPRC5 nPRC6 dummy3 dummy4 T=Tpr3 Rc=RcPR3 aoi=phi_aoi
space sPRC3 nPRC6 nBSp Lp3 

# beam splitter and short Michelson arms
beamsplitter BS nBSp nBSy nBSx nBSs T=Tbs
space sMICH_Y nBSy nITMY1 L=25+Schnupp/2 phi=pi/2
space sMICH_X nBSx nITMX1 L=25-Schnupp/2

# X arm cavity
mirror ITMX nITMX1 nITMX2 T=Titm Rc=RcITM L=Losses_arm
space sXCAV nITMX2 nETMX1 L=Larm phi=-pi*DARMtuning/1.064e-6
mirror ETMX nETMX1 nETMX2 T=Tetm Rc=RcETM L=Losses_arm
cavity sXCAV

# Y arm cavity
mirror ITMY nITMY1 nITMY2 T=Titm Rc=RcITM L=Losses_arm
space sYCAV nITMY2 nETMY1 L=Larm phi=pi*DARMtuning/1.064e-6
mirror ETMY nETMY1 nWTMY2 T=Tetm Rc=RcETM L=Losses_arm
cavity sYCAV

# signal recycling mirror and cavity common part
space sSR3 nBSs nSRC1 L=Ls3 phi=-SRCphi/2
beamsplitter SR3 nSRC1 nSRC2 dummy5 dummy6 T=Tsr3 Rc=RcSR3 aoi=phi_aoi
space sSR2 nSRC2 nSRC3 L=Ls2
beamsplitter SR2 nSRC4 nSRC3 dummy7 dummy8 T=Tsr2 Rc=RcSR2 aoi=phi_aoi
space sSRM nSRC4 nSRC5 L=Ls1
mirror SRM nSRC5 nSRC6 T=Tsrm Rc=RcSRM


### Detectors #############################################################

# Powers
power PRC  nPRC2   from=PRM
power XCAV nITMX2  from=ITMX
power YCAV nITMY2  from=ITMY
power SRC  nSRC1   from=sSR3
power AP   nSRC6   from=SRM


### Driving points ########################################################
driver drv  sXCAV sYCAV ITMX ITMY ETMX ETMY
radiationpressure  ITMX ITMY ETMX ETMY

vacuum qv nSRC6 into=SRM

## Homodyne readout
space sHomo1 nSRC6 nAP1 L=25
space sHomodyne nPO1 nHomo L=25
beamsplitter BS_Homo nAP1 nPD1 nPD2 nHomo R=0.5
powermeter PD1 nPD1
powermeter PD2 nPD2