LowT LCGT (wire is 1.6mm thick for both mirrors)

Off[General::"spell1"]
Off[General::"spell"]

SetDirectory[NotebookDirectory[]];

hmirrorstrITM[f_]=Import["hmirrorstrITMsap.m"];
hmirrorthermoITM[f_]=Import["hmirrorthermoITMsap.m"];
hmirrorcoaITM[f_]=Import["hmirrorcoaITMsap.m"];
hsuspITM[f_]=Import["hsuspITMsap.m"];
hmirrorstrETM[f_]=Import["hmirrorstrETMsap.m"];
hmirrorthermoETM[f_]=Import["hmirrorthermoETMsap.m"];
hmirrorcoaETM[f_]=Import["hmirrorcoaETMsap.m"];
hsuspETM[f_]=Import["hsuspETMsap2.m"]; (* thick wire *)

hmirror[f_]=Sqrt[hmirrorstrITM[f]^2+hmirrorthermoITM[f]^2+hmirrorstrETM[f]^2+hmirrorthermoETM[f]^2+hmirrorcoaITM[f]^2+hmirrorcoaETM[f]^2];
hsusp[f_]=Sqrt[hsuspITM[f]^2+hsuspETM[f]^2];

Seismic motion

Gseismic[f_] = 10^(-9)/f^2;(* seismic motion (m/Hz^(1/2)) *)

Hiso[f_] = 10^(-3)/f^6;(* total isolation ratio *)

hseis[f_] = 2/l*Gseismic[f]*Hiso[f];

hseis[f_]=Sqrt[(2*(10^(-17))*(f^(-6.5)))^2+(2*(10^(-16))*(f^(-8)))^2];

ITM reflectivity

T=0.004;

1.Parameters (for LCGT)

1.1 Physical constants

hb=1.05457266912510183 (10^(-34));(* reduced Planck constant (J*s) *)
ω0=1.8 (10^15);
c=2.99792458000000117`*^8;(* speed of light (m/s) *)
Ω=2 π f;
kB=1.38*10^(-23);(* Boltzmann's constant (J/K) *)
g=9.8;(* acceleration of the gravity (m/s^2) *)
Gravity=6.673*10^(-11);(* Gravitational constant (m^3/Kg/s^2) *)
solarmass=1.989*10^(30);(* mass of Sun (Kg) *)
Mpc=365.2422*24*60*60*c*3.26*10^6;(* 1 Mpc (m) *)

1.2 Laser

lambda=1064*10^(-9);(* wavelength (m) *)
P0= 75;(* power into interderometer(W)*)

1.3 Main cavity

l=3*10^3;(* length of cavity (m) *)

1.4 Interferometer (see 2.3.2)

Gpower=11;(* power recycling gain *)

2.Optical readout noise (no ζ)

2.1 Additional parameter settings

m=30; (* test mass (kg) *)
L=l; (* arm length (m) *)
I0=P0*Gpower; (* incident power to the beamsplitter *)

2.2 Basic equations for RSE

hSQL=(Sqrt[((8 hb)/(m (Ω^2) (L^2)))]);

Sh=((hSQL^2)/(2 κ))(((Abs[C11 Sin[ζ]+C21 Cos[ζ]])^2)+((Abs[C12 Sin[ζ]+C22 Cos[ζ]])^2)+((Abs[P12 Sin[ζ]+P22 Cos[ζ]])^2)+((Abs[P11 Sin[ζ]+P21 Cos[ζ]])^2)+((Abs[Q12 Sin[ζ]+Q22 Cos[ζ]])^2)+((Abs[Q11 Sin[ζ]+Q21 Cos[ζ]])^2)+((Abs[N11 Sin[ζ]+N21 Cos[ζ]])^2)+((Abs[N12 Sin[ζ]+N22 Cos[ζ]])^2)+(((Abs[M]*(Sqrt[Sadd])))^2))/((τ^2) ((Abs[D1 Sin[ζ]+D2 Cos[ζ]])^2));

M=1+(ρ^2)Exp[4 I β]-2ρ(Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+λSR ρ(-ρ Exp[2 I β]+Cos[2ϕ]+(κ/2)Sin[2ϕ])Exp[2 I β]+ϵ ρ(2((Cos[β])^2)(-ρ Exp[2 I β]+Cos[2ϕ])+(κ/2)(3+Exp[2 I β])Sin[2ϕ])Exp[2 I β];
C11=(Sqrt[1-λPD])((1+(ρ^2)) (Cos[2 ϕ]+(κ/2) Sin[2 ϕ])-2 ρ Cos[2 β]-(1/4)ϵ(-2(((1+Exp[2 I β]))^2)ρ+4(1+(ρ^2))((Cos[β])^2)Cos[2ϕ]+(3+Exp[2 I β])κ(1+(ρ^2))Sin[2 ϕ])+λSR(Exp[2 I β]ρ-(1/2)(1+(ρ^2))(Cos[2 ϕ]+(κ/2)Sin[2ϕ])));
C12=(Sqrt[1-λPD])(τ^2) ( -Sin[2 ϕ]-κ  ((Sin[ϕ])^2)+(1/2)ϵ Sin[ϕ]((3+Exp[2 I β])κ Sin[ϕ]+4 ((Cos[β])^2)Cos[ϕ])+(1/2)λSR(Sin[2ϕ]+κ ((Sin[ϕ])^2)));
C21=(Sqrt[1-λPD])(τ^2) (Sin[2 ϕ]-κ  ((Cos[ϕ])^2)+(1/2)ϵ Cos[ϕ]((3+Exp[2 I β])κ Cos[ϕ]+4 ((Cos[β])^2)Sin[ϕ])+(1/2)λSR(-Sin[2ϕ]+κ ((Cos[ϕ])^2))) ;
C22=C11;
D1=(Sqrt[1-λPD])(-(1+ρ Exp[2 I β]) Sin[ϕ]+(1/4)ϵ(3+ρ+2ρ Exp[4 I β]+(1+5ρ)Exp[2 I β])Sin[ϕ]+(1/2)λSR Exp[2 I β]ρ Sin[ϕ]);
D2=(Sqrt[1-λPD])(-(-1+ρ Exp[2 I β]) Cos[ϕ]+(1/4)ϵ(-3+ρ+2ρ Exp[4 I β]+(-1+5ρ)Exp[2 I β])Cos[ϕ]+(1/2)λSR Exp[2 I β]ρ Cos[ϕ]);
P11=(1/2)(Sqrt[1-λPD])(Sqrt[λSR])τ(-2ρ Exp[2 I β]+2Cos[2ϕ]+κ Sin[2ϕ]);
P12=-(Sqrt[1-λPD])(Sqrt[λSR])τ Sin[ϕ](2Cos[ϕ]+κ Sin[ϕ]);
P21=(Sqrt[1-λPD])(Sqrt[λSR])τ Cos[ϕ](2Sin[ϕ]-κ Cos[ϕ]);
P22=P11;
Q11=(Sqrt[λPD])(Exp[-2 I β]+(ρ^2)Exp[2 I β]-ρ(2 Cos[2ϕ]+κ Sin[2 ϕ])+(1/2)ϵ ρ(Exp[-2 I β]Cos[2ϕ]+Exp[2 I β](-2ρ-2ρ Cos[2 β]+Cos[2ϕ]+κ Sin[2ϕ])+2 Cos[2ϕ]+3 κ Sin[2ϕ])-(1/2)λSR ρ(2ρ Exp[2 I β]-2 Cos[2ϕ]-κ Sin[2ϕ]));
Q12=0;
Q21=0;
Q22=Q11;
N11=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(κ(1+ρ Exp[2 I β])Sin[ϕ]+2Cos[β](Exp[-I β]Cos[ϕ]-ρ Exp[I β](Cos[ϕ]+κ Sin[ϕ])));
N12=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(Exp[-I β]+ρ Exp[I β])Cos[β]Sin[ϕ];
N22=-(Sqrt[1-λPD])(Sqrt[2 ϵ])τ(-Exp[-I β]+ρ Exp[I β])Cos[β]Cos[ϕ];
N21=(Sqrt[1-λPD])(Sqrt[(ϵ/2)])τ(-κ(1+ρ)Cos[ϕ]+2Cos[β](Exp[-I β]+ρ Exp[I β])Cos[β] Sin[ϕ]);

γ=T c/(4 L);(* cavity pole *)
τ=(Sqrt[1-(ρ^2)]); (* SRM transmittance *)
β=ArcTan[Ω/γ]; (* phase shift in the arm cavity *)
κ=((2 (I0/ISQL) (γ^4))/((Ω^2) ((γ^2)+(Ω^2)))); (* coefficient that shows how much the mirror moves *)
ISQL=((m (L^2) (γ^4))/(4 ω0)); (* the power with which the quantum noise reaches the SQL at the cavity pole frequency *)

2.3 Loss parameters

roundtriploss=100*10^(-6); (* ppm; new! *)
ϵ = 2/T*roundtriploss; (* loss parameter of arms defined in KLMTV paper *)
λSR =0.02; (* loss in power at the signal recycling mirror *)
λPD=0.1;  (* 1 - PD's quantum efficiency in power *)
Sadd= 0*((π^2)/8 - 1);

3.Observable distance (Compact binary coalescense)

3.1 Parameters

m1=1.4*solarmass;(* mass of a compact object (Kg) *)
m2=1.4*solarmass;(* mass of other compace object (Kg) *)
mtotal=m1+m2;(* total moss of binary system (Kg) *)
mreduce=m1*m2/mtotal;(* reduced mass of binary system (Kg) *)
fmin=20;(* low cut off frequency of integral (Hz) *)
fmax=c^3/(6^(3/2)*Pi*Gravity*mtotal);(* high cut off frequency of integral (Hz) *)
SNR=8;(* threshold of Signal to Noise Ratio *)

3.2 Observable distance (Optimal case)

3.2.1 Integration

fmid=300;
Nini=60;
Nmid=20;

integ092=((∑_(ff=1)^Nini)(1/(f^(7/3)*(Sh+hsusp[f]^2+hmirror[f]^2+hseis[f]^2))*(fmid-fmin)/Nini/.f->fmin+(fmid-fmin)*(ff-0.5)/Nini)/.ρ->0.92)+((∑_(ff=1)^Nmid)(1/(f^(7/3)*(Sh+hsusp[f]^2+hmirror[f]^2+hseis[f]^2))*(fmax-fmid)/Nmid/.f->fmid+(fmax-fmid)*(ff-0.5)/Nmid)/.ρ->0.92);

vRSE

Optrho=0.92;

Range092=FindMaximum[(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc,{{ϕ,1.0,1.6},{ζ,0.01,1.57}}]

RangeBRSE092=FindMaximum[(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc/.ϕ->π/2,{ζ,0.01,1.57}]

OptPhi=ϕ/.Range092[[2]][[1]];

OptZetaD=ζ/.Range092[[2]][[2]]

OptZetaB=ζ/.RangeBRSE092[[2]][[1]]

PlotBRSE=LogLogPlot[(Sqrt[Sh])/.ρ->Optrho/.ϕ->π/2/.ζ->OptZetaB,{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.1]];
PlotDRSE=LogLogPlot[(Sqrt[Sh])/.ρ->Optrho/.ϕ->OptPhi/.ζ->OptZetaD,{f,1,(10^4)},PlotRange->{(1/(10^25)),(1/(10^20))},PlotStyle->Hue[0.5]];

4. Result with classical noise

Range092[[1]]

RangeBRSE092[[1]]

(1/SNR)/Sqrt[2]*2*(Gravity/c^3)^(5/6)*c*(5/96*mreduce)^(1/2)*(mtotal/Pi^2)^(1/3)*Sqrt[4*integ092]/Mpc/.ϕ->π/2/.ζ->π/2

Math to Igor

logDataOutput[filename_String, X_, {imin_, imax_}] :=
  Module[{strm},
    strm = OpenWrite[filename];
    Do[
      Do[
        Module[{},
          Map[writeList[strm, #] &, { x , X} /. x -> (10^i) 10^ j];
          writeListn[strm];
          ],
        {i, 0.001, 1, 0.001}
        ],
      {j, imin, imax}
      ];
    Close[strm];
    ]

writeList[strm_, dat_] :=
  WriteString[strm, ToString[FortranForm[dat]], " "];

writeListn[strm_] :=
  WriteString[strm, "\n"];

logDataOutput["LowT/LCGTQN_VDRSE.dat",(Sqrt[Sh])/.ρ->Optrho/.ϕ->OptPhi/.ζ->OptZetaD/.{f->x},{0,3}]

logDataOutput["LowT/LCGTQN_BRSE_HD.dat",(Sqrt[Sh])/.ρ->Optrho/.ϕ->π/2/.ζ->OptZetaB/.{f->x},{0,3}]

logDataOutput["LowT/LCGTQN_BRSE.dat",(Sqrt[Sh])/.ρ->Optrho/.ϕ->π/2/.ζ->π/2/.{f->x},{0,3}]

logDataOutput["LowT/hmirror.dat",hmirror[f]/.{f->x},{0,3}]

logDataOutput["LowT/hsusp.dat",hsusp[f]/.{f->x},{0,3}]

logDataOutput["LowT/hseis.dat",hseis[f]/.{f->x},{0,3}]

logDataOutput["LowT/hSQL.dat",hSQL/.{f->x},{0,3}]

logDataOutput["LowT/detail/hmirrorstr.dat",Sqrt[hmirrorstrITM[f]^2+hmirrorstrETM[f]^2]/.{f->x},{0,3}]

logDataOutput["LowT/detail/hmirrorthermo.dat",Sqrt[hmirrorthermoITM[f]^2+hmirrorthermoETM[f]^2]/.{f->x},{0,3}]

logDataOutput["LowT/detail/hmirrorcoa.dat",Sqrt[hmirrorcoaITM[f]^2+hmirrorcoaETM[f]^2]/.{f->x},{0,3}]

logDataOutput["LowT/totalVDRSE.dat",(Sqrt[Sh+hmirror[f]^2+hseis[f]^2+hsusp[f]^2])/.ρ->Optrho/.ϕ->OptPhi/.ζ->OptZetaD/.{f->x},{0,3}]

logDataOutput["LowT/totalBRSEHD.dat",(Sqrt[Sh+hmirror[f]^2+hseis[f]^2+hsusp[f]^2])/.ρ->Optrho/.ϕ->π/2/.ζ->OptZetaB/.{f->x},{0,3}]